Partilhar via

Reduza as suas emissões de carbono no Azure

A otimização de carbono no Azure funciona com o Azure Advisor para fornecer recomendações de otimização. O Consultor do Azure identifica recursos ociosos e subutilizados e mostra as economias de carbono e de custos associadas à implementação das recomendações. As recomendações podem incluir o desligamento de máquinas virtuais inativas e o dimensionamento correto de máquinas virtuais. Para obter mais recomendações e informações sobre o Azure Advisor, consulte Reduzir custos de serviço usando o Azure Advisor.

Para visualizar as recomendações de otimização de carbono, navegue até a página de Redução de Emissões e selecione a assinatura desejada e os grupos de recursos.

Esta página mostra o número total de recomendações disponíveis e potenciais oportunidades de poupança em termos de custos e carbono. Além disso, mostra equivalentes de economia de carbono conforme calculado pela calculadora de Equivalentes de Gases de Efeito Estufa da Agência de Proteção Ambiental dos Estados Unidos .

Ver recomendações

A lista de recomendações na tabela mostra recursos utilizados de forma ineficiente que podem ajudar a reduzir as emissões de carbono. Cada recomendação mostra as economias de carbono associadas e as potenciais economias de custos que podem advir de agir de acordo com uma recomendação.

Agir de acordo com a recomendação

Para agir de acordo com a recomendação, selecione o nome do recurso ou o texto na coluna Recomendação. A seleção do texto de recomendação leva você à página de ação do recurso. Por exemplo, a página de redimensionamento, a página de alteração de contagem de instâncias ou a página de visão geral de recursos para recomendações de exclusão.

Uma captura de tela mostrando a página de redução de emissões.

Converta a poupança de emissões em equivalentes

A calculadora de equivalências de gases de efeito estufa permite converter dados de emissões para a quantidade equivalente de dióxido de carbono (CO2) emitida usando essa quantidade. A calculadora ajuda você a traduzir medições abstratas em termos concretos que você pode entender, como as emissões anuais de árvores, residências ou sacos de lixo. Esta calculadora pode ser útil para comunicar a sua estratégia de redução de gases com efeito de estufa, metas de redução ou outras iniciativas destinadas a reduzir as emissões de gases com efeito de estufa.

Para saber mais sobre os tipos de recomendações, consulte Reduzir custos de serviço usando o Azure Advisor.

Recomendações de redução das emissões das exportações

Você pode exportar recomendações de redução de emissões usando o Azure Resource Graph. Execute a seguinte consulta no Azure Resource Graph Explorer. Depois, você pode baixar os resultados como CSV.

A exportação inclui:

  • ID da recomendação
  • ID da subscrição/Nome da subscrição
  • Nome do grupo de recursos
  • Redução de custos mensais
  • Poupança mensal de carbono em quilogramas
  • Nome do recurso
  • Mensagem de recomendação
  • Tipo de recomendação
  • Detalhes sobre a recomendação, incluindo os metadados do recurso, como ID do recurso e nome da função
// Export emissions reduction recommendations using Azure Resource Graph

advisorresources
  | where tolower(type) == "microsoft.advisor/recommendations"
  | extend RecommendationTypeId = tostring(properties.recommendationTypeId)
  | where RecommendationTypeId in ("94aea435-ef39-493f-a547-8408092c22a7", "e10b1381-5f0a-47ff-8c7b-37bd13d7c974")
  | project stableId=name, subscriptionId, resourceGroup, properties, recommendationId=id
  | join kind=leftouter(
      advisorresources
      | where tolower(type) == 'microsoft.advisor/suppressions'
      | extend tokens = split(id, '/')
      | extend stableId = iff(array_length(tokens) > 3, tokens[(array_length(tokens)-3)], '')
      | extend expirationTimeStamp = todatetime(iff(strcmp(tostring(properties.ttl), '-1') == 0, '9999-12-31', properties.expirationTimeStamp))
      | where expirationTimeStamp > now()
      | project suppressionId = tostring(properties.suppressionId), stableId, expirationTimeStamp
  ) on stableId
  | join kind = leftouter (
      advisorresources
      | where tolower(type) == 'microsoft.advisor/configurations'
      | where isempty(resourceGroup) == true
      | project subscriptionId, excludeRecomm = properties.exclude, lowCpuThreshold = properties.lowCpuThreshold
  ) on subscriptionId
  | extend isActive = iff(isempty(excludeRecomm), true, tobool(excludeRecomm) == false)
  | extend isNotExcludedViaCpuThreshold = iff((isnotempty(lowCpuThreshold) and isnotnull(properties.extendedProperties) and isnotempty(properties.extendedProperties.MaxCpuP95)),
      todouble(properties.extendedProperties.MaxCpuP95) < todouble(lowCpuThreshold),
      iff((isnull(properties.extendedProperties) or isempty(properties.extendedProperties.MaxCpuP95) or todouble(properties.extendedProperties.MaxCpuP95) < 100),
          true,
          false))
  | where isActive == true and isNotExcludedViaCpuThreshold == true
  | join kind = leftouter (
      advisorresources
      | where type =~ 'microsoft.advisor/configurations'
      | where isnotempty(resourceGroup) == true
      | project subscriptionId, resourceGroup, excludeProperty = properties.exclude
  ) on subscriptionId, resourceGroup
  | extend shouldBeIncluded = iff(isempty(excludeProperty), true, tobool(excludeProperty) == false)
  | where shouldBeIncluded == true
  | summarize expirationTimeStamp = max(expirationTimeStamp), suppressionIds = make_list(suppressionId) by recommendationId, stableId, subscriptionId, resourceGroup, tostring(properties)
  | extend isRecommendationActive = (isnull(expirationTimeStamp) or isempty(expirationTimeStamp))
  | extend properties = parse_json(properties)
  | extend monthlyCostSavings = toreal(properties.extendedProperties.savingsAmount)
  | extend monthlyCarbonSavingsKg = toreal(properties.extendedProperties.PotentialMonthlyCarbonSavings)
  | where monthlyCarbonSavingsKg > 0
  | extend resourceId = properties.resourceMetadata.resourceId, resourceName = tostring(properties.extendedProperties.roleName), recommendationMessage = properties.extendedProperties.recommendationMessage, recommendationType=tostring(properties.extendedProperties.recommendationType)
  | project recommendationId, subscriptionId, resourceGroup, suppressionIds, isRecommendationActive, monthlyCostSavings, monthlyCarbonSavingsKg, resourceId, resourceName, recommendationMessage, recommendationType| where isRecommendationActive == true| order by monthlyCarbonSavingsKg desc

Próximos passos

  • Last updated on