Partilhar via

Práticas recomendadas de FinOps para armazenamento

Este artigo descreve uma coleção de práticas comprovadas de FinOps para serviços de armazenamento. Ele fornece estratégias para otimizar custos, melhorar a eficiência e usar consultas do Azure Resource Graph (ARG) para obter informações sobre seus recursos de armazenamento. Seguindo essas práticas, você pode garantir que seus serviços de armazenamento sejam econômicos e estejam alinhados com as metas financeiras da sua organização.


Cópia de segurança

As seções a seguir fornecem consultas ARG para serviços de backup. Essas consultas ajudam você a obter informações sobre seus recursos de backup e garantir que eles estejam configurados com as configurações apropriadas. Ao analisar itens de backup e identificar backups ociosos, você pode otimizar seus serviços de backup para obter eficiência de custos.

Consulta: Backups ociosos

Esta consulta ARG analisa itens de backup nos Cofres dos Serviços de Recuperação do Azure e identifica os que não foram submetidos a backup por mais de 90 dias.

Categoria

Otimização

Consulta

recoveryservicesresources
| where type =~ 'microsoft.recoveryservices/vaults/backupfabrics/protectioncontainers/protecteditems'
| extend vaultId = tostring(properties.vaultId)
| extend resourceId = tostring(properties.sourceResourceId)
| extend idleBackup= datetime_diff('day', now(), todatetime(properties.lastBackupTime)) > 90
| extend  resourceType=tostring(properties.workloadType)
| extend protectionState=tostring(properties.protectionState)
| extend lastBackupTime=tostring(properties.lastBackupTime)
| extend resourceGroup=strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup)
| extend lastBackupDate=todatetime(properties.lastBackupTime)
| where idleBackup != 0
| project resourceId,vaultId,idleBackup,lastBackupDate,resourceType,protectionState,lastBackupTime,location,resourceGroup,subscriptionId

Consulta: Listar cofres de serviços de recuperação

Esta consulta do Azure Resource Graph (ARG) obtém detalhes dos Cofres de Recuperação do Azure. A consulta também inclui informações sobre a camada de SKU, configurações de redundância e outros metadados relevantes.

Categoria

Otimização

Consulta

resources
| where type == 'microsoft.recoveryservices/vaults'
| where resourceGroup in ({ResourceGroup})
| extend skuTier = tostring(sku['tier'])
| extend skuName = tostring(sku['name'])
| extend resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| extend redundancySettings = tostring(properties.redundancySettings['standardTierStorageRedundancy'])
| order by id asc
| project id, redundancySettings, resourceGroup, location, subscriptionId, skuTier, skuName

Discos

As seções a seguir fornecem consultas ARG para serviços de disco. Essas consultas ajudam você a obter informações sobre seus recursos de disco e garantir que eles estejam configurados com as configurações apropriadas. Ao analisar instantâneos de disco e identificar discos ociosos, você pode otimizar seus serviços de disco para obter eficiência de custos.

Consulta: Discos ociosos

Esta consulta ARG identifica discos gerenciados ociosos ou desanexados em seu ambiente do Azure.

Categoria

Otimização

Consulta

resources
| where type =~ 'microsoft.compute/disks' and managedBy == ""
| extend diskState = tostring(properties.diskState)
| where managedBy == ""
    and diskState != 'ActiveSAS'
    and tags !contains 'ASR-ReplicaDisk'
    and tags !contains 'asrseeddisk'
| extend DiskId=id, DiskIDfull=id, DiskName=name, SKUName=sku.name, SKUTier=sku.tier, DiskSizeGB=tostring(properties.diskSizeGB), Location=location, TimeCreated=tostring(properties.timeCreated), SubId=subscriptionId
| order by DiskId asc 
| project DiskId, DiskIDfull, DiskName, DiskSizeGB, SKUName, SKUTier, resourceGroup, Location, TimeCreated, subscriptionId

Consulta: Instantâneo de disco com mais de 30 dias

Esta consulta ARG identifica instantâneos de disco mais antigos que 30 dias.

Categoria

Otimização

Consulta

resources
| where type == 'microsoft.compute/snapshots'
| extend TimeCreated = properties.timeCreated
| extend resourceGroup = strcat("/subscriptions/",subscriptionId,"/resourceGroups/",resourceGroup)
| where TimeCreated < ago(30d)
| order by id asc 
| project id, resourceGroup, location, TimeCreated, subscriptionId

Consulta: Snapshot usando armazenamento premium

Esta consulta ARG identifica instantâneos de disco que estão utilizando armazenamento premium.

Categoria

Otimização

Consulta

resources
| where type == 'microsoft.compute/snapshots'
| extend
    StorageSku = tostring(sku.tier),
    resourceGroup = strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup),
    diskSize = tostring(properties.diskSizeGB)
| where StorageSku == "Premium"
| project id, name, StorageSku, diskSize, location, resourceGroup, subscriptionId

Contas de armazenamento

A seção a seguir fornece uma consulta ARG para contas de armazenamento. Ele ajuda você a obter informações sobre seus recursos de armazenamento e garantir que eles estejam configurados com as configurações apropriadas. Ao analisar contas de armazenamento e identificar tipos de contas de armazenamento herdadas, você pode otimizar seus serviços de armazenamento para obter eficiência de custos.

Consulta: Conta de armazenamento v1

Esta consulta ARG identifica contas de armazenamento que ainda estão usando o tipo v1 herdado, que podem não fornecer os mesmos recursos e eficiências que os tipos de conta de armazenamento mais recentes.

Categoria

Otimização

Consulta

resources
| where type =~ 'Microsoft.Storage/StorageAccounts'
    and kind !='StorageV2'
    and kind !='FileStorage'
| where resourceGroup in ({ResourceGroup})
| extend
    StorageAccountName = name,
    SAKind = kind,
    AccessTier = tostring(properties.accessTier),
    SKUName = sku.name,
    SKUTier = sku.tier,
    Location = location
| order by id asc
| project
    id,
    StorageAccountName,
    SKUName,
    SKUTier,
    SAKind,
    AccessTier,
    resourceGroup,
    Location,
    subscriptionId

Enviar comentários

Dê-nos a sua opinião com uma breve avaliação. Usamos essas análises para melhorar e expandir as ferramentas e os recursos do FinOps.

Enviar comentários

Se você está procurando algo específico, vote em uma ideia existente ou crie uma nova. Partilhe ideias com outras pessoas para obter mais votos. Focamo-nos nas ideias mais votadas.

Votar ou sugerir ideias


Conteúdos relacionados

Recursos relacionados:

Soluções relacionadas:


  • Last updated on